SAP 판매오더 품목 VL10C SUBMIT PROGRAM 오류

 

미처리 건수 숫자를 더블클릭하게 되면 다음 프로그램으로 이동하게 된다.

USER_COMMAND에서 SUBMIT 설정을 하고 VL10C인 판매오더품목을 불러오게 만들었다.

 

VL10C 판매 오더 품목 페이지

 

FORM USER_COMMAND USING P_UCOMM LIKE SY-UCOMM P_SELFIELD TYPE SLIS_SELFIELD.
 CASE P_UCOMM.
  WHEN '&IC1'.
   READ TABLE  GT_ITAB INDEX P_SELFIELD-TABINDEX.
   IF SY-SUBRC = 0.
 CASE P_SELFIELD-TABINDEX.
 
  WHEN '1'.     "판매문서까지 대기상태
   SUBMIT RVV50R10C
    WITH ST_LEDAT IN R_WADAT
    WITH ST_AUART NE 'ZLZO'
    WITH ST_LIFSP = SPACE
    WITH P_LERUL = '2'
    WITH ZS_KZAZU = 'X'
    AND RETURN.
    
    ENDCASE.
    ENDIF.
 ENDCASE.
ENDFORM.

< 고치기 전 코드 >

 

이렇게 적어도 잘 페이지가 넘어갔다. 하지만 맨 첫번째 페이지가 말썽이었는데..

 

자꾸 로그인하고 맨 처음 페이지만 '판매오더, 빠른조회' 페이지가 나오는것이다.

알고보니 사용자 역할의 시나리오 번호 문제였던것.

티코드 SE93으로 들어간다.

 

 

들어가서 ‘판매 오더 품목’인 VL10C를 적어줌.

 

 

여기서보면 VL10C는 트랜잭션 VL10X를 불러오는걸 볼 수 있다.

 

 

VL10X에서 시나리오 값을 ‘0001’로 불러오면

 

 

내가 불러오고자 하는 페이지랑 다른 페이지인것을 확인 할 수 있다.

그래서 판매오더 VL10C 페이지를 불러올때는 결국 SUBMIT 는 사용하지 못한다!!

 

PERFORM문을 만들어서 불러오기로함.

 

요렇게

 

DATA:
    LX_PARAMETERS     TYPE SHP_VL10_PARAMETERS,
    LX_SELECT_OPTIONS TYPE SHP_VL10_SELECT_OPTIONS,
    LT_DELIVERY          TYPE SHP_VL10_DELIVERY.

  DATA:
    LF_PROFILNAME     TYPE SHP_VL10_LIST_PROFILNAME,
    LF_PROGNAME      TYPE SYREPID,
    LF_SUBRC            TYPE SYSUBRC,
    LX_LIST_PROFIL    TYPE SHP_VL10_LIST_PROFIL,
    LS_T186V            TYPE T186V .

  DATA:
    LT_RANGE TYPE SHP_ABLAD_RANGE_T,
    LS_RANGE TYPE SHP_ABLAD_RANGE.

* Get List-Profil-data if given or from default values
  PERFORM PROFIL_DATA_COMPLETE(SAPLV50R_PRE) USING    '0101'
                                        LF_PROFILNAME
                               CHANGING LS_T186V
                                        LX_LIST_PROFIL.

  LX_LIST_PROFIL-HU_PAFCTN = '2'.
  LX_LIST_PROFIL-LEDAT_HIGH = GT_TDAT.

*..오더유형이 ZLZ0가 아닌것
  CLEAR:LT_RANGE[].
  LS_RANGE-SIGN  = 'I'.
  LS_RANGE-OPTION = 'NE'.
  LS_RANGE-LOW  = 'ZLZO'.
  APPEND LS_RANGE TO LT_RANGE.
  LX_SELECT_OPTIONS-AUART[] = LT_RANGE[].

  CLEAR:LT_RANGE[].
  LT_RANGE[] = R_WADAT[].
  LX_SELECT_OPTIONS-LEDAT[] = LT_RANGE[].

*..납품보류가 빈칸인것
  CLEAR:LT_RANGE[].
  LS_RANGE-SIGN  = 'I'.
  LS_RANGE-OPTION = 'EQ'.
  LS_RANGE-LOW  = SPACE.
  APPEND LS_RANGE TO LT_RANGE.
  LX_SELECT_OPTIONS-LIFSP[] = LT_RANGE[].

"배송 마감일 파라미터/셀렉옵션
  CALL FUNCTION 'SHP_EXTENDED_DUE_LIST'
    EXPORTING
      IX_LIST_PROFIL    = LX_LIST_PROFIL "디폴트값
      IX_PARAMETERS     = LX_PARAMETERS
      IX_SELECT_OPTIONS = LX_SELECT_OPTIONS
    IMPORTING
      EX_DELIVERY       = LT_DELIVERY
    EXCEPTIONS
      OTHERS            = 1.

 

GT_TDAT 는 내가 따로 설정한 날짜 데이터다.  EX) 2024.01.01

R_WADAT 마찬가지로 따로 설정한 날짜 데이터다.  EX) RANGES : R_WADAT FOR ZSD0000-WADAT.

 

이렇게 설정하게 되면 '0001'인 빠른 실행은 나오지 않고 '0101'만 나오게됨.